@REM is the equivalent of a comment in batch file syntax. Put an @ sign before
@REM anything you don't want to see printed in the cmd prompt.

@REM First do a find/replace for all the file paths. If you are using Windows XP
@REM you'll just have to replace "realmap" with whatever the name of your real map
@REM is, and "botmap" with whatever the name of your bot map is. If you're using
@REM Vista or something else, you'll have to change the whole file path because
@REM they won't be the same.

@REM So the DEL part just gets rid of all the old versions of your realmap and
@REM botmap before you start compiling. fixaas seems to have problems just over-
@REM writing things.

DEL "C:\Program Files\Quake iii arena\baseq3\maps\realmap.aas"
DEL "C:\Program Files\Quake iii arena\baseq3\maps\realmap.bak"
DEL "C:\Program Files\Quake iii arena\baseq3\maps\realmap.bsp"
DEL "C:\Program Files\Quake iii arena\baseq3\maps\realmap.prt"
DEL "C:\Program Files\Quake iii arena\baseq3\maps\realmap.srf"
DEL "C:\Program Files\Quake iii arena\baseq3\maps\botmap.bak"
DEL "C:\Program Files\Quake iii arena\baseq3\maps\botmap.bsp"
DEL "C:\Program Files\Quake iii arena\baseq3\maps\botmap.prt"
DEL "C:\Program Files\Quake iii arena\baseq3\maps\botmap.srf"

@REM This part sets the paths to your game folder, q3map2 folder, etc., so you
@REM don't have to keep typing them in.

set Q3_PATH="C:\Program Files\Quake iii arena"
set COMP_PATH="C:\Program Files\Quake iii arena\q3map2\q3map2.exe"
set BOT_PATH="C:\Program Files\Quake iii arena\q3map2\bspc.exe"
set MAP_PATH="C:\Program Files\Quake iii arena\baseq3\maps\realmap.map"
set GEN_OPTIONS=-fs_basepath %Q3_PATH%

@REM We begin our compile by doing a quick BSP of the real map.

%COMP_PATH% -meta %GEN_OPTIONS% %MAP_PATH%

@REM Then we set the map path to our bot map so we can compile for it.

set MAP_PATH="C:\Program Files\Quake iii arena\baseq3\maps\botmap.map"

@REM Do a bsp of the bot map so we can make the AAS.

%COMP_PATH% -meta %GEN_OPTIONS% %MAP_PATH%

@REM Create an AAS of the bot map with BSPC. -forcesidesvisible is necessary be-
@REM cause we used the -meta tag in our BSP.

%BOT_PATH% -forcesidesvisible -bsp2aas %MAP_PATH%

@REM Rename the botmap.ass to realmap.aas so we can join the two later with fixaas.

ren "C:\Program Files\Quake III Arena\baseq3\maps\botmap.aas" realmap.aas

@REM Set map path back to the real map for fixaas.

set MAP_PATH="C:\Program Files\Quake iii arena\baseq3\maps\realmap.map"

@REM You should now have a realmap.map and a realmap.aas (which is actually just
@REM your botmap.aas renamed).

@REM We now run fixaas on the real map so the .aas we renamed will work with it.
@REM Then compile the BSP however you want the final version of the map to look.
@REM This is just a -meta for quick testing.

%COMP_PATH% -fixaas %GEN_OPTIONS% %MAP_PATH%
%COMP_PATH% -meta %GEN_OPTIONS% %MAP_PATH%

@REM This runs an optimize on the AAS. The reason you have to do this is a really
@REM weird one. It's necessary because the date modified on the .aas has to be
@REM more recent than the one on the real map - please don't ask why, I have no
@REM clue  : ).

%BOT_PATH% -optimize -reach %MAP_PATH%

@REM Freeze the cmd prompt so you can go back and look for error msgs if this
@REM didn't work. You can add this anywhere if you want to pause the process at
@REM any point and check what's going on.

pause