Your world is waiting...
https://www.quake3world.com/forum/
Code: Select all
@echo off
REM compileq1map.cmd -- compile a quake 1 map
REM usage: "compileq1map.cmd <mapname> [-t]"
REM -t: test mode (quick compile, a bit uglier), final is assumed if omitted
REM written by spirit
REM settings -- adapt to your needs
@set COMPPATH="C:\games\nquake\id1\hmap2.exe"
@set MAPPATH="C:\games\nquake\id1\maps\%1.map"
REM here we go - no need to mess with stuff below this line
REM check for args
if {%1} == {} (call :HELP) & (goto :EOF)
%COMPPATH% %MAPPATH%
if {%2} == {-t} (call :TEST) & (goto :EOF)
%COMPPATH% -vis %MAPPATH%
%COMPPATH% -light -extra4x4 %MAPPATH%
echo "done (full quality)"
goto :EOF
:TEST
%COMPPATH% -vis -fast %MAPPATH%
%COMPPATH% -light %MAPPATH%
echo "done (fast)."
goto :EOF
:HELP
echo USAGE
echo =====
echo "compileq1map <mapname> [-t]"
echo "<mapname>: name of your mapfile, no extension"
echo "-t: test compile (faster but a bit ugly)"
echo -----------------------------------------------
goto :EOF
:EOF