Quake3World

Code: Select all

@echo off
@echo Q3Map2 Batch Compiler 3.1 - 10.05.04
@echo Obsidian
@echo.

REM // BSP SWITCHES:		-meta -patchmeta 4-20 (default=8 q3default=4) -subdivisions (q3default=4) -skyfix
REM // VIS SWITCHES:		-vis -fast -saveprt
REM // RAD QUICK:		-light -fast -patchshadows -gamma 2 -compensate 4
REM // RAD TEMP:		-fastbounce -bounce 3-8 -samplesize 8-16? -dirty
REM // RAD SWITCHES4 (ydnar):	-light -fast -patchshadows -samples 3 -bounce 8 -gamma 2 -compensate 4 -dirty

set MAPNAME=sm_surfacelight
set BSPPARM=-meta -skyfix
set VISPARM=-vis -saveprt
set RADPARM=-light -fast -patchshadows -gamma 2 -compensate 4
set AASPARM=-forcesidesvisible -optimize
set GENPARM=-v

@echo -----------------------------------------------------------
@echo MAP: %MAPNAME%
@echo BSP: %BSPPARM%
@echo VIS: %VISPARM%
@echo RAD: %RADPARM%
@echo AAS: %AASPARM%
@echo -----------------------------------------------------------
@echo.
@echo Ready to run Q3Map2 . . .
PAUSE

set GAMEDIR=C:\Games\Quake III Arena
set FS_GAME=obsidian
set Q3MAP2=C:\Program Files\GtkRadiant\Compilers\Q3Map2\q3map2.exe
set BSPC=C:\Program Files\GtkRadiant\Compilers\BSPC\bspc.exe
set LOGDUMP=C:\Program Files\GtkRadiant\Compilers\Zlog

@echo.

@echo Compiling BSP . . .
del "%LOGDUMP%\1bsp.log"
"%Q3MAP2%" %BSPPARM% %GENPARM% -fs_game %FS_GAME% "%GAMEDIR%\%FS_GAME%\maps\%MAPNAME%.map" >>"%LOGDUMP%\1bsp.log"

@echo Compiling VIS . . .
del "%LOGDUMP%\2vis.log"
"%Q3MAP2%" %VISPARM% %GENPARM% -fs_game %FS_GAME% "%GAMEDIR%\%FS_GAME%\maps\%MAPNAME%.map" >>"%LOGDUMP%\2vis.log"

@echo Compiling LIGHT . . .
del "%LOGDUMP%\3rad.log"
"%Q3MAP2%" %RADPARM% %GENPARM% -fs_game %FS_GAME% "%GAMEDIR%\%FS_GAME%\maps\%MAPNAME%.map" >>"%LOGDUMP%\3rad.log"

@echo Q3Map2 compile complete
@echo.

@echo Ready to run BSPC . . .
PAUSE

@echo.

@echo Compiling AAS . . .
del "%LOGDUMP%\4aas.log"
"%BSPC%" -bsp2aas "%GAMEDIR%\%FS_GAME%\maps\%MAPNAME%.bsp" %AASPARM% >>"%LOGDUMP%"\4aas.log"
del bspc.log

@echo BSPC compile complete
@echo.

@echo Finished
PAUSE